ESP8266 – WiFi Station
Kiến thức
Để kết nối được vào mạng Internet, thì đầu tiên ESP8266 phải kết nối vào mạng WiFi nội bộ, và mạng WiFi nội bộ phải có kết nối WAN Internet. Đa phần các Modem hiện nay đều tích hợp luôn cả WiFi Access Point, do đó khá dễ dàng trong việc triển khai các ứng dụng IoT.
Khi muốn kết nối vào mạng WiFi cục bộ thì ESP8266 cần phải hoạt động ở chế độ Station (STA), đồng thời nó phải được cung cấp tên (SSID) và mật khẩu mạng WiFi.
Mỗi Access Point đều yêu cầu một phương thức mã hóa để Station sử dụng nhằm tạo kết nối – ví dụ các phương thức WEP, WPA2, tuy nhiên chúng ta có lẽ không cần quan tâm nhiều, vì ESP8266 sẽ tự động thực hiện các thao tác lựa chọn phương thức mã hóa.
Khi kết nối thành công vào mạng WiFi thì ESP8266 sẽ khởi động DHCP Client (mặc định) để xin cấp phát địa chỉ IP trước khi bắt đầu các kết nối IP. Do đó, nếu như vì lý do gì đó, mà Access Point của bạn không có DHCP Server để cấp phát IP thì bạn phải cấu hình IP tĩnh cho ESP8266.
Kết nối vào mạng WiFi nội bộ
Với đoạn code này, nếu bạn cung cấp đúng SSID và PASSWORD, đồng thời Access Point hoạt động thì thiết bị sẽ kết nối và in ra Serial Terminal địa chỉ IP của ESP8266 trong mạng LAN
#include <ESP8266WiFi.h>
const char* ssid = "your-ssid";
const char* password = "your-password";
void setup() {
// Thiết lập truyền dữ liệu nối tiếp ở tốc độ 115200 bits/s
Serial.begin(115200);
delay(10);
Serial.print("Connecting to ");
// In ra tên mạng wifi sẽ kết nối đến
Serial.println(ssid);
// Thiết lập ESP8266 ở chế độ station và kết nối đến mạng wifi đã chỉ định
WiFi.begin(ssid, password);
// Đoạn code in ra dấu . nếu ESP8266 chưa được kết nối
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
// In ra dòng "WiFi connected" và địa chỉ IP của ESP8266
Serial.println("");
Serial.println("WiFi connected");
Serial.println("IP address: ");
Serial.println(WiFi.localIP());
}
void loop() {
}Thay đổi SSID và Password bạn đang sử dụng. Nạp chương trình cho board NodeMCU và xem kết quả hiển trị trên màn hình Monitor.
-
Trong thời gian chờ đợi kết nối, Monitor sẽ in ra đoạn log
. . . . -
Khi board NodeMCU kết nối được với router của bạn, Monitor sẽ hiển thị địa chỉ IP mà router cấp cho nó.
Sử dụng WiFiMulti
Tuy nhiên, đôi lúc ứng dụng bạn cần nồi đồng cối đá, thì có 2-3 mạng WiFi để backup là bình thường, class WiFiMulti sẽ giúp bạn điều đó. Cùng với một hàm monitor đơn giản để báo cho các chức năng khác biết khi mạng đã được thiết lập.
#include <ESP8266WiFi.h>
#include <ESP8266WiFiMulti.h>
// Khai báo biến wifiMulti thuộc class ESP8266WiFiMulti để sử dụng các chức năng của class này.
ESP8266WiFiMulti wifiMulti;
// Biến connectioWasAlive nhằm kiểm tra kết nối của ESP8266 đến mạng wifi.
boolean connectioWasAlive = true;
void setup()
{
Serial.begin(115200);
Serial.println();
// Add vào các mạng wifi mà ESP8266 được chỉ định sẽ kết nối
wifiMulti.addAP("primary-network-name", "pass-to-primary-network");
wifiMulti.addAP("secondary-network-name", "pass-to-secondary-network");
wifiMulti.addAP("tertiary-network-name", "pass-to-tertiary-network");
}
void monitorWiFi()
{
// Kiểm tra nếu chưa kết nối đến 1 mạng wifi nào sẽ cài đặt connectioWasAlive = false
// đồng thời in ra dấu "." sau mỗi 500ms nếu chưa được kết nối.
if (wifiMulti.run() != WL_CONNECTED)
{
if (connectioWasAlive == true)
{
connectioWasAlive = false;
Serial.print("Looking for WiFi ");
}
Serial.print(".");
delay(500);
}
// Nếu đã kết nối đến 1 trong các mạng wifi sẽ in ra tên mạng wifi và set connectioWasAlive = true
// để khi mất kết nối chương trình sẽ vào phần if (connectioWasAlive == true) nhằm thông báo đang
// tìm kiếm mạng wifi
else if (connectioWasAlive == false)
{
connectioWasAlive = true;
Serial.printf(" connected to %s\n", WiFi.SSID().c_str());
}
}
void loop()
{
monitorWiFi();
}Điền các thông tin WiFi mà bạn có thể kết nối được. Nạp chương trình cho board NodeMCU và xem kết quả hiển trị trên màn hình Monitor.
